Import chromium-64.0.3282.140

third_party/WebKit/Source/bindings/modules/BUILD.gn

@@ -0,0 +1,200 @@
+# Copyright 2014 Tfe Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//third_party/WebKit/Source/modules/modules.gni")
+import("//third_party/WebKit/Source/bindings/scripts/scripts.gni")
+import("//third_party/WebKit/Source/build/scripts/scripts.gni")
+
+group("bindings_modules_generated") {
+  visibility = [ "//third_party/WebKit/*" ]
+  public_deps = [
+    ":event_modules",
+    ":event_modules_names",
+    ":event_target_modules_names",
+    ":modules_bindings_generated_event_interfaces",
+  ]
+}
+
+generate_event_interfaces("modules_bindings_generated_event_interfaces") {
+  sources = [
+    "//third_party/WebKit/Source/modules/app_banner/BeforeInstallPromptEvent.idl",
+    "//third_party/WebKit/Source/modules/background_fetch/BackgroundFetchClickEvent.idl",
+    "//third_party/WebKit/Source/modules/background_fetch/BackgroundFetchEvent.idl",
+    "//third_party/WebKit/Source/modules/background_fetch/BackgroundFetchFailEvent.idl",
+    "//third_party/WebKit/Source/modules/background_fetch/BackgroundFetchedEvent.idl",
+    "//third_party/WebKit/Source/modules/background_sync/SyncEvent.idl",
+    "//third_party/WebKit/Source/modules/device_orientation/DeviceMotionEvent.idl",
+    "//third_party/WebKit/Source/modules/device_orientation/DeviceOrientationEvent.idl",
+    "//third_party/WebKit/Source/modules/encryptedmedia/MediaEncryptedEvent.idl",
+    "//third_party/WebKit/Source/modules/encryptedmedia/MediaKeyMessageEvent.idl",
+    "//third_party/WebKit/Source/modules/gamepad/GamepadEvent.idl",
+    "//third_party/WebKit/Source/modules/indexeddb/IDBVersionChangeEvent.idl",
+    "//third_party/WebKit/Source/modules/mediarecorder/BlobEvent.idl",
+    "//third_party/WebKit/Source/modules/mediastream/MediaStreamEvent.idl",
+    "//third_party/WebKit/Source/modules/mediastream/MediaStreamTrackEvent.idl",
+    "//third_party/WebKit/Source/modules/notifications/NotificationEvent.idl",
+    "//third_party/WebKit/Source/modules/payments/AbortPaymentEvent.idl",
+    "//third_party/WebKit/Source/modules/payments/CanMakePaymentEvent.idl",
+    "//third_party/WebKit/Source/modules/payments/PaymentRequestEvent.idl",
+    "//third_party/WebKit/Source/modules/payments/PaymentRequestUpdateEvent.idl",
+    "//third_party/WebKit/Source/modules/peerconnection/RTCDTMFToneChangeEvent.idl",
+    "//third_party/WebKit/Source/modules/peerconnection/RTCDataChannelEvent.idl",
+    "//third_party/WebKit/Source/modules/peerconnection/RTCPeerConnectionIceEvent.idl",
+    "//third_party/WebKit/Source/modules/presentation/PresentationConnectionAvailableEvent.idl",
+    "//third_party/WebKit/Source/modules/presentation/PresentationConnectionCloseEvent.idl",
+    "//third_party/WebKit/Source/modules/push_messaging/PushEvent.idl",
+    "//third_party/WebKit/Source/modules/sensor/SensorErrorEvent.idl",
+    "//third_party/WebKit/Source/modules/serviceworkers/ExtendableEvent.idl",
+    "//third_party/WebKit/Source/modules/serviceworkers/ExtendableMessageEvent.idl",
+    "//third_party/WebKit/Source/modules/serviceworkers/FetchEvent.idl",
+    "//third_party/WebKit/Source/modules/serviceworkers/InstallEvent.idl",
+    "//third_party/WebKit/Source/modules/speech/SpeechRecognitionError.idl",
+    "//third_party/WebKit/Source/modules/speech/SpeechRecognitionEvent.idl",
+    "//third_party/WebKit/Source/modules/speech/SpeechSynthesisEvent.idl",
+    "//third_party/WebKit/Source/modules/storage/StorageEvent.idl",
+    "//third_party/WebKit/Source/modules/vr/VRDisplayEvent.idl",
+    "//third_party/WebKit/Source/modules/vr/latest/VRDeviceEvent.idl",
+    "//third_party/WebKit/Source/modules/vr/latest/VRSessionEvent.idl",
+    "//third_party/WebKit/Source/modules/webaudio/AudioProcessingEvent.idl",
+    "//third_party/WebKit/Source/modules/webaudio/OfflineAudioCompletionEvent.idl",
+    "//third_party/WebKit/Source/modules/webgl/WebGLContextEvent.idl",
+    "//third_party/WebKit/Source/modules/webmidi/MIDIConnectionEvent.idl",
+    "//third_party/WebKit/Source/modules/webmidi/MIDIMessageEvent.idl",
+    "//third_party/WebKit/Source/modules/websockets/CloseEvent.idl",
+  ]
+  output_file = "event_modules_names.json5"
+  suffix = "Modules"
+}
+
+make_event_factory("event_modules") {
+  visibility = [ ":*" ]
+  in_files = [ "$root_gen_dir/blink/event_modules_names.json5" ]
+  outputs = [
+    "$blink_modules_output_dir/event_modules_factory.cc",
+  ]
+  deps = make_core_generated_deps + [ "//third_party/WebKit/Source/bindings/modules:modules_bindings_generated_event_interfaces" ]
+  deps += [
+    "//device/vr:mojo_bindings_blink",
+    "//media/midi:mojo_blink",
+    "//services/device/public/interfaces:generic_sensor_blink",
+  ]
+}
+
+make_names("event_modules_names") {
+  visibility = [ ":*" ]
+  in_files = [ "$root_gen_dir/blink/event_modules_names.json5" ]
+  output_dir = blink_modules_output_dir
+  deps = make_core_generated_deps + [ "//third_party/WebKit/Source/bindings/modules:modules_bindings_generated_event_interfaces" ]
+}
+
+make_names("event_target_modules_names") {
+  visibility = [ ":*" ]
+  in_files = [ "../../modules/event_target_modules_names.json5" ]
+  output_dir = blink_modules_output_dir
+}
+
+# ------------------------------------------------------------------------------
+
+compute_interfaces_info_individual("interfaces_info_individual_modules") {
+  sources = modules_static_interface_idl_files + modules_definition_idl_files +
+            modules_static_dependency_idl_files +
+            modules_generated_dependency_idl_files
+
+  interfaces_info_file =
+      "$bindings_modules_output_dir/InterfacesInfoOverallIndividual.pickle"
+  component_info_file =
+      "$bindings_modules_output_dir/ComponentInfoModules.pickle"
+  deps = [
+    ":modules_core_global_constructors_idls",
+    ":modules_global_constructors_idls",
+  ]
+}
+
+action("interfaces_info") {
+  script = "$bindings_scripts_dir/compute_interfaces_info_overall.py"
+
+  inputs = [
+    "$bindings_core_output_dir/InterfacesInfoCoreIndividual.pickle",
+    "$bindings_modules_output_dir/InterfacesInfoOverallIndividual.pickle",
+  ]
+  outputs = [
+    "$bindings_modules_output_dir/InterfacesInfoOverall.pickle",
+  ]
+
+  args = [
+    "--",
+    rebase_path("$bindings_core_output_dir/InterfacesInfoCoreIndividual.pickle",
+                root_build_dir),
+    rebase_path(
+        "$bindings_modules_output_dir/InterfacesInfoOverallIndividual.pickle",
+        root_build_dir),
+    rebase_path("$bindings_modules_output_dir/InterfacesInfoOverall.pickle",
+                root_build_dir),
+  ]
+
+  public_deps = [
+    ":interfaces_info_individual_modules",
+    "//third_party/WebKit/Source/bindings/core:interfaces_info_individual_core",
+  ]
+}
+
+compute_global_objects("modules_global_objects") {
+  sources = modules_idl_files
+  sources_generated = [ "$bindings_core_output_dir/GlobalObjectsCore.pickle" ]
+  output_file = "$bindings_modules_output_dir/GlobalObjectsModules.pickle"
+  deps = [
+    "//third_party/WebKit/Source/bindings/core:core_global_objects",
+  ]
+}
+
+generate_global_constructors("modules_core_global_constructors_idls") {
+  sources = core_idl_files + core_idl_with_modules_dependency_files
+  global_objects_file =
+      "$bindings_modules_output_dir/GlobalObjectsModules.pickle"
+  interfaces = modules_core_global_constructors_original_interfaces
+  basenames = modules_core_global_constructors_original_interface_basenames
+  component = "core"
+  output_dir = blink_modules_output_dir
+  deps = [
+    ":modules_global_objects",
+  ]
+}
+
+generate_global_constructors("modules_global_constructors_idls") {
+  sources = modules_idl_files
+  global_objects_file =
+      "$bindings_modules_output_dir/GlobalObjectsModules.pickle"
+  interfaces = modules_global_constructors_original_interfaces
+  basenames = modules_global_constructors_original_interface_basenames
+  component = "modules"
+  output_dir = blink_modules_output_dir
+  deps = [
+    ":modules_global_objects",
+  ]
+}
+
+# Compile the sources produced above. This will get linked into "modules".
+source_set("generated") {
+  visibility = [ "//third_party/WebKit/Source/modules:*" ]
+
+  sources = get_target_outputs(":event_modules") +
+            get_target_outputs(":event_modules_names") +
+            get_target_outputs(":event_target_modules_names")
+
+  configs += [
+    "//third_party/WebKit/Source:config",
+    "//third_party/WebKit/Source/modules:modules_implementation",
+    "//third_party/WebKit/Source:non_test_config",
+    "//third_party/WebKit/Source:inside_blink",
+  ]
+
+  deps = [
+    ":event_modules",
+    ":event_modules_names",
+    ":event_target_modules_names",
+    "//third_party/WebKit/Source/core",
+    "//third_party/WebKit/Source/platform/wtf",
+    "//v8",
+  ]
+}

third_party/WebKit/Source/bindings/modules/v8/BUILD.gn

@@ -0,0 +1,157 @@
+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//third_party/WebKit/Source/bindings/modules/v8/generated.gni")
+import("//third_party/WebKit/Source/bindings/scripts/scripts.gni")
+import("//third_party/WebKit/Source/modules/modules.gni")
+import("//third_party/WebKit/Source/modules/modules_idl_files.gni")
+
+visibility = [ "//third_party/WebKit/*" ]
+
+group("bindings_modules_v8_generated") {
+  public_deps = [
+    ":bindings_modules_impl_generated",
+    ":bindings_modules_v8_generated_init_partial",
+    ":generate_bindings_modules_v8_interfaces",
+    ":generate_bindings_modules_v8_partial_interfaces",
+    ":generate_bindings_modules_v8_partial_interfaces_for_testing",
+    ":generate_v8_context_snapshot_external_references",
+  ]
+}
+
+idl_compiler("generate_bindings_modules_v8_interfaces") {
+  sources = modules_definition_idl_files
+  output_dir = bindings_modules_v8_output_dir
+  output_name_suffix = ""
+  target_component = "modules"
+}
+
+idl_impl("bindings_modules_impl_generated") {
+  dict_idls = modules_dictionary_idl_files
+  non_dict_outputs = bindings_modules_generated_union_type_files +
+                     generated_modules_callback_function_files
+  non_dict_output_dir = bindings_modules_v8_output_dir
+  target_component = "modules"
+}
+
+idl_compiler("generate_bindings_modules_v8_partial_interfaces") {
+  sources = core_idl_with_modules_dependency_files
+  output_dir = bindings_modules_v8_output_dir
+  output_name_suffix = "Partial"
+  if (snake_case_source_files) {
+    output_name_suffix = "_partial"
+  }
+  target_component = "modules"
+}
+
+idl_compiler("generate_bindings_modules_v8_partial_interfaces_for_testing") {
+  sources = webcore_testing_idl_with_modules_dependency_files
+  output_dir = bindings_modules_v8_output_dir
+  output_name_suffix = "Partial"
+  if (snake_case_source_files) {
+    output_name_suffix = "_partial"
+  }
+  target_component = "modules"
+}
+
+generate_origin_trial_features("bindings_modules_origin_trial_features") {
+  sources =
+      modules_idl_files + modules_global_constructors_generated_idl_files +
+      modules_dependency_idl_files
+  component = "Modules"
+  output_dir = bindings_modules_output_dir + "/v8"
+  deps = [
+    "//third_party/WebKit/Source/bindings/modules:modules_global_constructors_idls",
+  ]
+}
+
+action("bindings_modules_v8_generated_init_partial") {
+  script = "$bindings_scripts_dir/generate_init_partial_interfaces.py"
+
+  inputs = [
+    "$bindings_modules_output_dir/InterfacesInfoOverall.pickle",
+  ]
+  outputs = [
+    bindings_modules_generated_init_partial_interfaces_file,
+  ]
+
+  # Put the IDL file list in a response file to avoid command-line limits.
+  response_file_contents =
+      rebase_path(core_idl_with_modules_dependency_files, root_build_dir)
+
+  args = [
+    "--idl-files-list",
+    "{{response_file_name}}",
+    "--output",
+    rebase_path(bindings_modules_generated_init_partial_interfaces_file,
+                root_build_dir),
+  ]
+  if (snake_case_source_files) {
+    args += [ "--snake-case-generated-files" ]
+  }
+
+  deps = [
+    "//third_party/WebKit/Source/bindings/modules:interfaces_info",
+  ]
+}
+
+blink_modules_sources("bindings_modules_impl") {
+  # ":generate_bindings_modules_v8_partial_interfaces_for_testing" is not
+  # included here.
+  sources =
+      get_target_outputs(":generate_bindings_modules_v8_interfaces") +
+      get_target_outputs(":bindings_modules_impl_generated") +
+      get_target_outputs(":generate_bindings_modules_v8_partial_interfaces") +
+      get_target_outputs(":bindings_modules_v8_generated_init_partial") +
+      get_target_outputs(":bindings_modules_origin_trial_features")
+
+  deps = [
+    ":bindings_modules_origin_trial_features",
+    ":bindings_modules_v8_generated",
+  ]
+
+  if (!is_component_build && is_win) {
+    # This target as a static library (for non-component builds) is >4GB on
+    # Windows, this causes linking to fail. As a workaround, split it into
+    # multiple shards.
+    split_count = 5
+  }
+}
+
+action("generate_v8_context_snapshot_external_references") {
+  script = "$bindings_scripts_dir/generate_v8_context_snapshot_external_references.py"
+  idl_files = core_idl_files + core_idl_with_modules_dependency_files +
+              modules_definition_idl_files
+  output = bindings_generated_v8_context_snapshot_external_references_file
+
+  inputs = idl_files + [ script ]
+  outputs = [
+    output,
+  ]
+
+  response_file_contents = rebase_path(idl_files, root_build_dir)
+  args = [
+    "--cache-dir",
+    rebase_path(bindings_scripts_output_dir, root_build_dir),
+    "--output",
+    rebase_path(output, root_build_dir),
+    "--idl-files-list",
+    "{{response_file_name}}",
+    "--info-dir",
+    rebase_path("$bindings_output_dir", root_build_dir),
+    "--target-component",
+    "modules",
+  ]
+  if (snake_case_source_files) {
+    args += [ "--snake-case-generated-files" ]
+  }
+
+  deps = [
+    "//third_party/WebKit/Source/bindings/core:interfaces_info_individual_core",
+    "//third_party/WebKit/Source/bindings/modules:interfaces_info",
+    "//third_party/WebKit/Source/bindings/modules:interfaces_info_individual_modules",
+    "//third_party/WebKit/Source/bindings/scripts:cached_jinja_templates",
+    "//third_party/WebKit/Source/bindings/scripts:cached_lex_yacc_tables",
+  ]
+}

third_party/WebKit/Source/bindings/modules/v8/custom/custom.gni

@@ -0,0 +1,11 @@
+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+# Make the files absolute so they can be imported to anywhere.
+bindings_modules_v8_custom_files =
+    get_path_info([
+                    "V8CustomSQLStatementErrorCallback.cpp",
+                    "V8ExtendableMessageEventCustom.cpp",
+                  ],
+                  "abspath")

third_party/WebKit/Source/bindings/modules/v8/generated.gni

@@ -0,0 +1,103 @@
+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/chrome_build.gni")
+import("//third_party/WebKit/Source/bindings/bindings.gni")
+import("//third_party/WebKit/Source/core/core_idl_files.gni")
+import("//third_party/WebKit/Source/modules/modules_idl_files.gni")
+
+bindings_modules_v8_output_dir = "$bindings_output_dir/modules/v8"
+
+bindings_modules_generated_init_partial_interfaces_file =
+    "$bindings_modules_v8_output_dir/initPartialInterfacesInModules.cpp"
+
+# TODO(bashi): It would be better to have a way to update this list automatically.
+bindings_modules_generated_union_type_files = [
+  "$bindings_modules_v8_output_dir/animation_effect_read_only_or_animation_effect_read_only_sequence.cc",
+  "$bindings_modules_v8_output_dir/animation_effect_read_only_or_animation_effect_read_only_sequence.h",
+  "$bindings_modules_v8_output_dir/array_buffer_or_array_buffer_view_or_dictionary.cc",
+  "$bindings_modules_v8_output_dir/array_buffer_or_array_buffer_view_or_dictionary.h",
+  "$bindings_modules_v8_output_dir/array_buffer_or_array_buffer_view_or_usv_string.cc",
+  "$bindings_modules_v8_output_dir/array_buffer_or_array_buffer_view_or_usv_string.h",
+  "$bindings_modules_v8_output_dir/array_buffer_view_or_blob_or_string_or_form_data.cc",
+  "$bindings_modules_v8_output_dir/array_buffer_view_or_blob_or_string_or_form_data.h",
+  "$bindings_modules_v8_output_dir/audio_context_latency_category_or_double.cc",
+  "$bindings_modules_v8_output_dir/audio_context_latency_category_or_double.h",
+  "$bindings_modules_v8_output_dir/boolean_or_constrain_boolean_parameters.cc",
+  "$bindings_modules_v8_output_dir/boolean_or_constrain_boolean_parameters.h",
+  "$bindings_modules_v8_output_dir/boolean_or_media_track_constraints.cc",
+  "$bindings_modules_v8_output_dir/boolean_or_media_track_constraints.h",
+  "$bindings_modules_v8_output_dir/byte_string_sequence_sequence_or_byte_string_byte_string_record.cc",
+  "$bindings_modules_v8_output_dir/byte_string_sequence_sequence_or_byte_string_byte_string_record.h",
+  "$bindings_modules_v8_output_dir/canvas_image_source.cc",
+  "$bindings_modules_v8_output_dir/canvas_image_source.h",
+  "$bindings_modules_v8_output_dir/client_or_service_worker_or_message_port.cc",
+  "$bindings_modules_v8_output_dir/client_or_service_worker_or_message_port.h",
+  "$bindings_modules_v8_output_dir/dictionary_or_string.cc",
+  "$bindings_modules_v8_output_dir/dictionary_or_string.h",
+  "$bindings_modules_v8_output_dir/document_timeline_or_scroll_timeline.cc",
+  "$bindings_modules_v8_output_dir/document_timeline_or_scroll_timeline.h",
+  "$bindings_modules_v8_output_dir/dom_exception_or_overconstrained_error.cc",
+  "$bindings_modules_v8_output_dir/dom_exception_or_overconstrained_error.h",
+  "$bindings_modules_v8_output_dir/double_or_constrain_double_range.cc",
+  "$bindings_modules_v8_output_dir/double_or_constrain_double_range.h",
+  "$bindings_modules_v8_output_dir/float32_array_or_float64_array_or_dom_matrix.cc",
+  "$bindings_modules_v8_output_dir/float32_array_or_float64_array_or_dom_matrix.h",
+  "$bindings_modules_v8_output_dir/html_canvas_element_or_offscreen_canvas.cc",
+  "$bindings_modules_v8_output_dir/html_canvas_element_or_offscreen_canvas.h",
+  "$bindings_modules_v8_output_dir/long_or_constrain_long_range.cc",
+  "$bindings_modules_v8_output_dir/long_or_constrain_long_range.h",
+  "$bindings_modules_v8_output_dir/offscreen_rendering_context.cc",
+  "$bindings_modules_v8_output_dir/offscreen_rendering_context.h",
+  "$bindings_modules_v8_output_dir/password_credential_data_or_html_form_element.cc",
+  "$bindings_modules_v8_output_dir/password_credential_data_or_html_form_element.h",
+  "$bindings_modules_v8_output_dir/point_2d_sequence_or_constrain_point_2d_parameters.cc",
+  "$bindings_modules_v8_output_dir/point_2d_sequence_or_constrain_point_2d_parameters.h",
+  "$bindings_modules_v8_output_dir/rtc_ice_candidate_init_or_rtc_ice_candidate.cc",
+  "$bindings_modules_v8_output_dir/rtc_ice_candidate_init_or_rtc_ice_candidate.h",
+  "$bindings_modules_v8_output_dir/rendering_context.cc",
+  "$bindings_modules_v8_output_dir/rendering_context.h",
+  "$bindings_modules_v8_output_dir/request_or_usv_string.cc",
+  "$bindings_modules_v8_output_dir/request_or_usv_string.h",
+  "$bindings_modules_v8_output_dir/request_or_usv_string_or_request_or_usv_string_sequence.cc",
+  "$bindings_modules_v8_output_dir/request_or_usv_string_or_request_or_usv_string_sequence.h",
+  "$bindings_modules_v8_output_dir/string_or_array_buffer_or_nfc_message.cc",
+  "$bindings_modules_v8_output_dir/string_or_array_buffer_or_nfc_message.h",
+  "$bindings_modules_v8_output_dir/string_or_canvas_gradient_or_canvas_pattern.cc",
+  "$bindings_modules_v8_output_dir/string_or_canvas_gradient_or_canvas_pattern.h",
+  "$bindings_modules_v8_output_dir/string_or_string_sequence.cc",
+  "$bindings_modules_v8_output_dir/string_or_string_sequence.h",
+  "$bindings_modules_v8_output_dir/string_or_string_sequence_or_constrain_dom_string_parameters.cc",
+  "$bindings_modules_v8_output_dir/string_or_string_sequence_or_constrain_dom_string_parameters.h",
+  "$bindings_modules_v8_output_dir/string_or_unsigned_long.cc",
+  "$bindings_modules_v8_output_dir/string_or_unsigned_long.h",
+  "$bindings_modules_v8_output_dir/unsigned_long_or_unsigned_long_sequence.cc",
+  "$bindings_modules_v8_output_dir/unsigned_long_or_unsigned_long_sequence.h",
+  "$bindings_modules_v8_output_dir/webgl_rendering_context_or_webgl2_rendering_context.cc",
+  "$bindings_modules_v8_output_dir/webgl_rendering_context_or_webgl2_rendering_context.h",
+]
+
+generated_modules_callback_function_files = [
+  "$bindings_modules_v8_output_dir/v8_decode_error_callback.cc",
+  "$bindings_modules_v8_output_dir/v8_decode_error_callback.h",
+  "$bindings_modules_v8_output_dir/v8_decode_success_callback.cc",
+  "$bindings_modules_v8_output_dir/v8_decode_success_callback.h",
+  "$bindings_modules_v8_output_dir/v8_database_callback.cc",
+  "$bindings_modules_v8_output_dir/v8_database_callback.h",
+  "$bindings_modules_v8_output_dir/v8_idb_observer_callback.cc",
+  "$bindings_modules_v8_output_dir/v8_idb_observer_callback.h",
+  "$bindings_modules_v8_output_dir/v8_media_session_action_handler.cc",
+  "$bindings_modules_v8_output_dir/v8_media_session_action_handler.h",
+  "$bindings_modules_v8_output_dir/v8_position_callback.cc",
+  "$bindings_modules_v8_output_dir/v8_position_callback.h",
+  "$bindings_modules_v8_output_dir/v8_position_error_callback.cc",
+  "$bindings_modules_v8_output_dir/v8_position_error_callback.h",
+  "$bindings_modules_v8_output_dir/v8_remote_playback_availability_callback.cc",
+  "$bindings_modules_v8_output_dir/v8_remote_playback_availability_callback.h",
+  "$bindings_modules_v8_output_dir/v8_vr_frame_request_callback.cc",
+  "$bindings_modules_v8_output_dir/v8_vr_frame_request_callback.h",
+]
+
+bindings_generated_v8_context_snapshot_external_references_file =
+    "$bindings_modules_v8_output_dir/V8ContextSnapshotExternalReferences.cpp"

third_party/WebKit/Source/bindings/modules/v8/v8.gni

@@ -0,0 +1,34 @@
+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("custom/custom.gni")
+
+# Make the files absolute so they can be imported to anywhere.
+bindings_modules_v8_files =
+    get_path_info([
+                    "serialization/SerializedScriptValueForModulesFactory.cpp",
+                    "serialization/SerializedScriptValueForModulesFactory.h",
+                    "serialization/V8ScriptValueDeserializerForModules.cpp",
+                    "serialization/V8ScriptValueDeserializerForModules.h",
+                    "serialization/V8ScriptValueSerializerForModules.cpp",
+                    "serialization/V8ScriptValueSerializerForModules.h",
+                    "ModuleBindingsInitializer.cpp",
+                    "ModuleBindingsInitializer.h",
+                    "ToV8ForModules.h",
+                    "V8BindingForModules.cpp",
+                    "V8BindingForModules.h",
+                    "V8ContextSnapshotExternalReferences.h",
+                    "wasm/WasmResponseExtensions.cpp",
+                    "wasm/WasmResponseExtensions.h",
+                    "WebGLAny.cpp",
+                    "WebGLAny.h",
+                  ],
+                  "abspath") + bindings_modules_v8_custom_files
+
+bindings_modules_v8_unittest_files =
+    get_path_info([
+                    "serialization/V8ScriptValueSerializerForModulesTest.cpp",
+                    "V8BindingForModulesTest.cpp",
+                  ],
+                  "abspath")