mirror of
https://github.com/espressif/esp-idf.git
synced 2026-10-02 03:00:34 +03:00
Frantisek Hrbata
cbd2482e00
Integrate the ldgen into cmakev2. With this change, it becomes possible to actually link the project executables. In cmakev2, the handling of linker scripts is deferred to idf_build_library, unlike in cmakev1, where linker scripts were added and generated during the target_linker_script call. In cmakev2, the target_linker_script only adds the linker scripts and templates, along with the output filenames for the linker scripts generated from the templates, to the component property. When idf_build_library is called and all the requested components are included, it uses the __get_target_dependencies function to obtain all transitively linked targets to the library interface target. These targets are mapped to the components, and the LIBRARY_COMPONENTS_LINKED library property is set. It contains all components linked to the library interface target. The components from LIBRARY_COMPONENTS_LINKED are used to collect linker fragments and linker scripts utilized in the library. Additionally, all targets transitively linked to the library are used to identify archive files used in the library. This includes component archives and archives added with the add_prebuilt_library function. The archives and ldfragments related to the components linked to the library are used when ldgen generates the linker scripts from templates. The linker scripts, both static and generated by ldgen, are added to the library interface link options and INTERFACE_LINK_DEPENDS property. For generated linker scripts, a custom target is created and added as a dependency for the library interface to ensure they are generated before the link. The difference compared to cmakev1 is that the generated linker scripts, currently only sections.ld, are not global in the project but are generated per library. This means there might be multiple versions of sections.ld depending on the components included in the library. For example, a component like esp_system may be linked to multiple library interface targets, each with a different set of components. This results in different sets of fragment files and library archives and different versions of the sections.ld linker script. This should ensure proper dependencies between targets. In other words, if a component changes its linker fragment, only executables linked to libraries using this component should be re-linked. As a consequence of this approach, the generated linker scripts for different libraries need to have different names or be stored in different directories to avoid overwriting the linker script for one library with the linker script for another library using the same component. This is handled with a suffix, which is based on the library interface target name and appended to the generated linker script. So, for example, there is no sections.ld, but instead sections.ld_fatfs_lib or sections.ld_hello_world_lib. As a next step, we can add a DEFAULT option to idf_build_library and avoid adding the suffix for the default library. Signed-off-by: Frantisek Hrbata <frantisek.hrbata@espressif.com>
94 lines
3.8 KiB
CMake
94 lines
3.8 KiB
CMake
include_guard(GLOBAL)
|
|
|
|
set(one_value LIBRARY TEMPLATE SUFFIX OUTPUT)
|
|
#[[
|
|
__ldgen_process_template(LIBRARY <target>
|
|
TEMPLATE <template>
|
|
OUTPUT <output>
|
|
[SUFFIX <suffix>])
|
|
|
|
:TARGET[in]: A library interface target that already has the properties
|
|
__LDGEN_LIBRARIES, __LDGEN_FRAGMENT_FILES, and __LDGEN_DEPENDS
|
|
set. These properties include libraries and fragment files for
|
|
components linked to the library interface.
|
|
:TEMPLATE[in]: Linker script template to process.
|
|
:OUTPUT[in]: The output filename where the generated linker script will be
|
|
saved.
|
|
:SUFFIX[in,opt]: Optional suffix for the generated files containing the list
|
|
of linked library archives.
|
|
|
|
Pass the linker script ``TEMPLATE`` to the linker script generation tool,
|
|
ldgen, for processing. The processed linker script is stored in the file
|
|
specified by the ``OUTPUT`` option.
|
|
|
|
This function can be called multiple times to generate multiple linker
|
|
scripts from a single template. For example, a component like esp_system may
|
|
be linked to multiple library interface targets, each with a different set
|
|
of components. This results in different sets of fragment files and library
|
|
archives. The suffix is used to ensure that the files listing the archives
|
|
are not overwritten.
|
|
#]]
|
|
function(__ldgen_process_template)
|
|
set(options)
|
|
set(one_value LIBRARY TEMPLATE SUFFIX OUTPUT)
|
|
set(multi_value)
|
|
cmake_parse_arguments(ARG "${options}" "${one_value}" "${multi_value}" ${ARGN})
|
|
|
|
if(NOT DEFINED ARG_LIBRARY)
|
|
idf_die("LIBRARY option is required")
|
|
endif()
|
|
|
|
if(NOT DEFINED ARG_TEMPLATE)
|
|
idf_die("TEMPLATE option is required")
|
|
endif()
|
|
|
|
if(NOT DEFINED ARG_OUTPUT)
|
|
idf_die("OUTPUT option is required")
|
|
endif()
|
|
|
|
idf_build_get_property(idf_path IDF_PATH)
|
|
idf_build_get_property(build_dir BUILD_DIR)
|
|
idf_build_get_property(sdkconfig SDKCONFIG)
|
|
idf_build_get_property(root_kconfig __ROOT_KCONFIG)
|
|
idf_build_get_property(python PYTHON)
|
|
idf_build_get_property(config_env_path __CONFIG_ENV_PATH)
|
|
|
|
idf_library_get_property(ldgen_libraries "${ARG_LIBRARY}" __LDGEN_LIBRARIES)
|
|
idf_library_get_property(ldgen_fragment_files "${ARG_LIBRARY}" __LDGEN_FRAGMENT_FILES)
|
|
idf_library_get_property(ldgen_depends "${ARG_LIBRARY}" __LDGEN_DEPENDS)
|
|
|
|
list(JOIN ldgen_libraries "\n" ldgen_libraries)
|
|
|
|
file(WRITE "${build_dir}/ldgen_libraries.in${ARG_SUFFIX}" "${ldgen_libraries}")
|
|
file(GENERATE OUTPUT "${build_dir}/ldgen_libraries${ARG_SUFFIX}"
|
|
INPUT "${build_dir}/ldgen_libraries.in${ARG_SUFFIX}")
|
|
|
|
set_property(DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
|
|
APPEND PROPERTY ADDITIONAL_CLEAN_FILES
|
|
"${build_dir}/ldgen_libraries.in${ARG_SUFFIX}"
|
|
"${build_dir}/ldgen_libraries${ARG_SUFFIX}")
|
|
|
|
if($ENV{LDGEN_CHECK_MAPPING})
|
|
set(ldgen_check "--check-mapping"
|
|
"--check-mapping-exceptions" "${idf_path}/tools/ci/check_ldgen_mapping_exceptions.txt")
|
|
idf_msg("Mapping check enabled in ldgen")
|
|
endif()
|
|
|
|
add_custom_command(
|
|
OUTPUT "${ARG_OUTPUT}"
|
|
COMMAND ${python} "${idf_path}/tools/ldgen/ldgen.py"
|
|
--config "${sdkconfig}"
|
|
--fragments-list "${ldgen_fragment_files}"
|
|
--input "${ARG_TEMPLATE}"
|
|
--output "${ARG_OUTPUT}"
|
|
--kconfig "${root_kconfig}"
|
|
--env-file "${config_env_path}"
|
|
--env "IDF_BUILD_V2=y"
|
|
--libraries-file "${build_dir}/ldgen_libraries${ARG_SUFFIX}"
|
|
--objdump "${CMAKE_OBJDUMP}"
|
|
${ldgen_check}
|
|
DEPENDS ${ARG_TEMPLATE} ${ldgen_fragment_files} ${ldgen_depends} ${sdkconfig}
|
|
VERBATIM
|
|
)
|
|
endfunction()
|